**** NOTE: Choose one of the following commands in order to load the Source Data **************************.
**** NOTE: You have to up-date the Directory according to the localization of the files in your computer ****.

GET DATA /TYPE=XLS
   /FILE='E:\JOP\Joplink.net\prev\201111\08_SourceData.xls'
   /SHEET=name '08_data'
   /CELLRANGE=full
   /READNAMES=on
   /ASSUMEDSTRWIDTH=32767.

GET
  FILE='E:\JOP\Joplink.net\prev\201111\08_SourceData.sav'.

*******************************************************************************************.
des all.
fre all.
**********************.
compute BMI=Weight/(Height*Height)*10000.
variable label BMI 'Body Mass Index (kg/m2)'.
format BMI (f4.1).
fre BMI.

recode BMI (low thru 25=1)(25 thru hi=2) into GROUP.
variable label GROUP 'Dicothomized BMI (Study Groups)'.
value labels GROUP 1 '<25 kg/m2' 2 '=>25 kg/m2'.
format GROUP (f1.0).

cro BMI by GROUP.

recode BMI (low thru 30=0)(30 thru hi=1) into BMI30DIC.
variable label BMI30DIC 'Dicothomized BMI (Standard Obesity Definition)'.
value labels BMI30DIC 0 '<30 kg/m2' 1 '=>30 kg/m2'.
format BMI30DIC (f1.0).

cro BMI by BMI30DIC.

*************************.
recode PDSize(low thru 3.0=1)(3.0 thru hi=0) into PDSizeDIC.
variable label PDSizeDIC 'Dicothomized PD Size'.
value labels PDSizeDIC 0 '>3 mm' 1 '<=3 mm'.
format PDSizeDIC (f1.0).

cro PDSize by PDSizeDIC.

*************************.

recode FistulaGrade (0=0)(1,2,3=1) into Fistula.
recode FistulaGrade (0,1=0)(2,3=1) into FistulaClinical.
variable label Fistula 'Presence of Fistula'.
variable label FistulaClinical 'Clinical Definition of Fistula'.
value labels Fistula 0 'Absent' 1 'Grades A,B,C'
                 /FistulaClinical 0 'No + Grade A' 1 'Grades B,C'
        .
format FistulaGrade  Fistula FistulaClinical (f1.0).

cro FistulaGrade BY Fistula FistulaClinical.

*************************.

compute Complication=0.
if (Fistula=1)                Complication=1.
if (DelayedEmptying=1)Complication=1.
if (Wound=1)               Complication=1.
if (Bleeding=1)             Complication=1.
if (Chyle=1)                 Complication=1.
if (BrainInfarction=1)     Complication=1.
variable label Complication 'Presence of Complications'.
value labels Complication 0 'No' 1 'Yes'.
format Complication (f1.0).

fre Complication.
cro Complication BY Fistula DelayedEmptying Wound Bleeding Chyle BrainInfarction .

compute No_of_Complication=
                       Fistula 
                    + DelayedEmptying 
                    + Wound 
                    + Bleeding 
                    + Chyle 
                    + BrainInfarction
                    .
variable label No_of_Complication  'Number of Complications'.
format No_of_Complication (f1.0).

fre No_of_Complication/sta=all.
fre Fistula DelayedEmptying Wound Bleeding Chyle BrainInfarction .

cro No_of_Complication BY Complication .

****************************************.
compute BloodLoss100=BloodLoss/100.
variable label BloodLoss100 'Recoded Blood Loss (x100 mL)'.
format BloodLoss100 (f5.1).

fre BloodLoss100 .

***************************************.

sort cases by ID.
des all.

SAVE OUTFILE='E:\JOP\Joplink.net\prev\201111\08_FinalData.sav'
 /COMPRESSED.